Problemas MSDTC em Windows Server 2003

Problema gerando o erro Event id 7024 no Windows Server 2003

Este problema foi detectado recentemente em diversos servidores e foi realizado o procedimento abaixo com sucesso.

Verifique se o EventID e o source são os mesmos, pois existem diversas variações de problemas envolvendo o MSDTC. Para maiores informações procure o link "Documentações MSDTC" na sessão "Documentações.

A realização do procedimento via batch é mais ágil e eficaz.

2 - Eventos

Event Type: Error
Event Source: MSDTC
Event Category: SVC
Event ID: 4112
Date: 2006-6-5
Time: 1:46:03
User: N/A
Computer: WIN2003R2
Description:
Could not start the MS DTC Transaction Manager.


Event Type: Error
Event Source: Service Control Manager
Event Category: None
Event ID: 7024
Date: 2006-6-5
Time: 1:44:04
User: N/A
Computer: WIN2003R2
Description:
The Distributed Transaction Coordinator service terminated with service-specific error 3221229584 (0xC0001010).

3 - Procedimentos

3.1 - Via Batch

3.1.1 - Copie as 4 batches para o servidor danificado.

3.1.2 - Execute as 3 primeiras na sequência.
3.1.3 - Reinicie o servidor.
3.1.4 - Logue no servidor e execute a batch 4.
3.1.5 - Verifique se o serviço MSDTC está startado e se acabaram as mensagens de erro no Event Viewer.

Segue os descritivos dos batchs copie na seqüencia e copie para o bloco de notas e salve com a extensão .bat

1 - BATCH

@echo off
if {%1}=={} @echo Syntax: MSDTC1 Filename&goto :EOF
setlocal ENABLEDELAYEDEXPANSION
set filename=%1
if exist %filename% del /q %filename%
(
@echo Alerter
@echo EventSystem
@echo Browser
@echo TrkWks
@echo Dnscache
@echo Eventlog
@echo PolicyAgent
@echo dmserver
@echo Messenger
@echo Netlogon
@echo NtLmSsp
@echo Netman
@echo PlugPlay
@echo RpcSs
@echo RpcLocator
@echo NtmsSvc
@echo SamSs
@echo lanmanserver
@echo SENS
@echo Schedule
@echo LmHosts
@echo winmgmt
@echo Wmi
@echo W32Time
@echo lanmanworkstation
)>"%TEMP%\MSDTC1.TMP"
call :stopdtc>nul 2>&1
for /f "Tokens=*" %%L in ('reg query HKLM\System\CurrentControlSet\Services^|FINDSTR /I /B /L /C:"HKEY_LOCAL_MACHINE"') do (
set line=%%L
set key=HKLM!LINE:~18!
call :subkey "!key!"
call :testsvc
)
endlocal
goto :EOF
:stopdtc
sc stop msdtc
goto :EOF
:testsvc
for /f "Tokens=*" %%c in ('@echo !svc!^|findstr /I /B /E /L /G:"%TEMP%\MSDTC1.TMP"') do goto :EOF
set /a start=3
set /a type=0
call :getstart>nul 2>&1
call :gettype>nul 2>&1
if %type% LSS 16 goto :EOF
if %start% NEQ 2 goto :EOF
sc config !svc! start= demand
@echo sc config !svc! start= auto>>%filename%
goto :EOF
:gettype
for /f "Tokens=2,3" %%x in ('reg query "HKLM\System\CurrentControlSet\Services\!svc!" /V type^|FIND "REG_DWORD"') do (
set /a type=%%y
)
goto :EOF
:getstart
for /f "Tokens=2,3" %%x in ('reg query "HKLM\System\CurrentControlSet\Services\!svc!" /V start^|FIND "REG_DWORD"') do (
set /a start=%%y
)
goto :EOF
:subkey
set svc=%~nx1

2 - BATCH

@echo off
setlocal
@echo %WINDIR%\System32\msdtc.exe -uninstall
%WINDIR%\System32\msdtc.exe -uninstall
call :delkey "HKCR\CID"
call :delkey "HKLM\SYSTEM\CurrentControlSet\Services\MSDTC"
call :delkey "HKLM\SYSTEM\ControlSet001\Services\MSDTC"
call :delkey "HKLM\SYSTEM\ControlSet002\Services\MSDTC"
call :delkey "HKLM\Software\Microsoft\MSDTC"
@echo %WINDIR%\System32\msdtc.exe -install
%WINDIR%\System32\msdtc.exe -install
endlocal
goto :EOF
:delkey
set key=%1
call :delkeyq %key% >nul 2>&1
@echo.
goto :EOF
:delkeyq
REG DELETE %key% /F

3 - BATCH

@echo off
if {%1}=={} @echo Syntax: MSDTC3 Filename&goto :EOF
if not exist %1 Syntax: MSDTC3 Filename - %1 was NOT found.&goto :EOF
setlocal
set filename=%1
for /f "Tokens=*" %%r in ('type %filename%') do (
%%r
)
reg add "HKLM\SOFTWARE\Microsoft\MSDTC\XADLL" /F
regsvr32 mtxoci.dll
endlocal1

4 - BATCH

@echo off
%WINDIR%\System32\msdtc.exe -resetlog

4 - Documentações

How to rebuild or move a MSDTC installation to be used with a SQL failover cluster
http://support.microsoft.com/kb/294209
http://blog.csdn.net/longrujun/archive/2006/06/04/772283.aspx
How to reinstall Microsoft Distributed Transaction Coordinator
http://support.microsoft.com/kb/891801
Documentação: MSDTC
http://technet.microsoft.com/en-us/library/cc726307%28WS.10%29.aspx


Espero que ajude.

ajuda de Rodrigo Reis (Mineiro)